[MWForum]Creating Fraction Materials

[Mike Sandy]

Let me add a couple of points to Wendy's suggestions.

Any method for drawing a circle with MWLogo
involves drawing a polygon.  If you are drawing a 360-
sided polygon then the length of a side of the polygon
will be approximately the length of segment of a circle
of the same radius, subtending 1° at the centre.
By simple proportion this is 2*pi*radius/360.
This is a very good approximation.

to circle :r :n :d
; :n  and :d are the numerator and denominator
; of the fraction
 pu cg home
 make "s 2 * pi * :r / 360
 pd fd :r lt 90 + .5 ;points turtle along polygon side
 repeat round 360 * :n / :d
   [fd :s lt 1]
  home pu
end

Alternatively use 2 turtles.
One to draw the sides of the polygon, the other
to find the vertices of the polygon.

to circle :r :n :d
 ask[t1 t2][ht pu home] ; both turtles in the centre.
 cg
 t1, pd fd :r ; sets t1 on circle and draws side of sector
t2,
 repeat round 360 * :n / :d
   [ lt 1 fd :r ; finds  next vertex
    t1, setpos ask "t2 [pos] ; t1 draws line to next vertex
    t2, bk :r] ;t2 returns to centre
 t1, home ;t1 draws final side of sector
end


Mike

----- Original Message ----- 
From: "Lauren Pacini" <lrpacini@yahoo.com>
To: <MWForum@lists.mathcats.com>
Sent: Monday, September 13, 2004 8:19 PM
Subject: [MWForum]Creating Fraction Materials


> Our 6th Grade students have been asked to make a new
> set of fraction materials (Montessori) for our Upper
> Elementary classrooms (4th through 6th grades).
>
> The materials are a series of fractional circles with
> a diameter of 20cm, ranging from 1/2 to 1/20 (180
> degrees to 13 degrees).
>
> It is easy enough to do the job using Excel, but I
> would like to try to use Microworlds 2.0. The students
> use LOGO for geometric constructions, so this would be
> an extension of that if it can be done.
>
> The bottom line is that they need to draw a circle
> with a 20cm diameter and then insert the radii -- all
> with LOGO.
>
> Can that be done?
>
> If so, I want to work the students through the
> discovery process to see if they can get there, but
> first I have to know where "THERE" is!!
>
> Thanks, all!!
>
> Lauren Pacini
> Ruffing Montessori School
> Cleveland Heights, Ohio
>
>
>
>
> __________________________________
> Do you Yahoo!?
> Yahoo! Mail - 50x more storage than other providers!
> http://promotions.yahoo.com/new_mail
> _______________________________________________
> MWForum mailing list
> MWForum@lists.mathcats.com
> http://lists.mathcats.com/mailman/listinfo/mwforum
> Attachments archived at:
> http://www.mathcats.com/mwforum/attachments.html
> To unsubscribe or for administrative questions contact
> mailto:mwforum-admin@lists.mathcats.com